Explanation
In this example, the goal is to count cells in a range that contain text values. This could be hard-coded text like “apple” or “red”, numbers entered as text, or formulas that return text values. Empty cells and cells that contain numeric values or errors should not be included in the count. This problem can be solved with the COUNTIF function or the SUMPRODUCT function. Both approaches are explained below. For convenience, data is the named range B5:B15.
COUNTIF function
The simplest way to solve this problem is with the COUNTIF function and the asterisk () wildcard . The asterisk () matches zero or more characters of any kind. For example, to count cells in a range that begin with “a”, you can use COUNTIF like this:
=COUNTIF(range,"a*") // begins with "a"
In this example, however, we don’t want to match any specific text value. We want to match all text values. To do this, we provide the asterisk (*) by itself for criteria. The formula in H5 is:
=COUNTIF(data,"*") // any text value
The result is 4 because there are four cells in data (B5:B15) that contain text values.
To reverse the operation of the formula and count all cells that do not contain text, add the not equal to (<>) logical operator like this:
=COUNTIF(data,"<>*") // non-text values
This is the formula used in cell H6. The result is 7, since there are seven cells in data (B5:B15) that do not contain text values.
COUNTIFS function
To apply more specific criteria, you can switch to the COUNTIFS function , which supports multiple conditions. For example, to count cells with text, but exclude cells that contain only a space character, you can use a formula like this:
=COUNTIFS(range,"*",range,"<> ")
This formula will count cells that contain any text value except a single space (" “).
SUMPRODUCT function
Another way to solve this problem is to use the SUMPRODUCT function with the ISTEXT function . SUMPRODUCT makes it easy to perform a logical test on a range, and then count the results. The test is performed with the ISTEXT function. True to its name, the ISTEXT function only returns TRUE when given a text value:
=ISTEXT("apple")// returns TRUE
=ISTEXT(70) // returns FALSE
To count cells with text values in the example shown, you can use a formula like this:
=SUMPRODUCT(--ISTEXT(data))
Working from the inside out, the logical test is based on the ISTEXT function:
ISTEXT(data)
Because data (B5:B15) contains 11 values, ISTEXT returns 11 results in an array like this:
{TRUE;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE}
In this array, the TRUE values correspond to cells that contain text values, and the FALSE values represent cells that do not contain text. To convert the TRUE and FALSE values to 1s and 0s, we use a double negative (–):
--{TRUE;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE}
The resulting array inside the SUMPRODUCT function looks like this:
=SUMPRODUCT({1;1;1;0;0;1;0;0;0;0;0}) // returns 4
With a single array to process, SUMPRODUCT sums the array and returns 4 as the result.
To reverse the formula and count all cells that do not contain text, you can nest the ISTEXT function inside the NOT function like this:
=SUMPRODUCT(--NOT(ISTEXT(data)))
The NOT function reverses the results from ISTEXT. The double negative (–) converts the array to numbers, and the array inside SUMPRODUCT looks like this:
=SUMPRODUCT({0;0;0;1;1;0;1;1;1;1;1}) // returns 7
The result is 7, since there are seven cells in data (B5:B15) that do not contain text values.
Note: the SUMPRODUCT formulas above may seem complex, but u sing Boolean operations in array formulas is powerful and flexible. It is also a n important skill in modern functions like FILTER and XLOOKUP , which often use this technique to select the right data. The syntax used by COUNTIF on the other hand is unique to a group of eight functions and is therefore not as useful or portable.
Explanation
In this example, the goal is to count cells that do not contain a specific substring. This problem can be solved with the COUNTIF function or the SUMPRODUCT function . Both approaches are explained below. Although COUNTIF is not case-sensitive, the SUMPRODUCT version of the formula can be adapted to perform a case-sensitive count. For convenience, data is the named range B5:B15.
COUNTIF function
The COUNTIF function counts cells in a range that meet supplied criteria. For example, to count the number of cells in a range that contain “apple” you can use COUNTIF like this:
=COUNTIF(range,"apple") // equal to "apple"
Note this is an exact match. To be included in the count, a cell must contain “apple” and only “apple”. If a cell contains any other characters, it will not be counted. To reverse this operation and count cells that do not contain “apple”, you can add the not equal to (<>) operator like this:
=COUNTIF(range,"<>apple") // not equal to "apple"
The goal in this example is to count cells that do not contain specific text, where the text is a substring that can be anywhere in the cell. To do this, we need to use the asterisk (*) character as a wildcard . To count cells that contain the substring “apple”, we can use a formula like this:
=COUNTIF(range,"*apple*") // contains "apple"
The asterisk (*) wildcard matches zero or more characters of any kind, so this formula will count cells that contain “apple” anywhere in the cell. To count cells that do not contain the substring “apple”, we add the not equal to (<>) operator like this:
=COUNTIF(range,"<>*apple*") // does not contain "apple"
The formulas used in the worksheet shown follow the same pattern:
=COUNTIF(data,"<>*a*") // does not contain "a"
=COUNTIF(data,"<>*0*") // does not contain "0"
=COUNTIF(data,"<>*-r*") // does not contain "-r"
Data is the named range B5:B15. The COUNTIF function supports three different wildcards, see this page for more details.
Note the COUNTIF formula above won’t work if you are targeting a particular number and cells contain numeric data. This is because the wildcard automatically causes COUNTIF to look for text only (i.e. to look for “2” instead of just 2). In addition, COUNTIF is not case-sensitive, so you can’t perform a case-sensitive count. The SUMPRODUCT alternative explained below can handle both situations.
With a cell reference
You can easily adjust this formula to use a cell reference in criteria . For example, if A1 contains the substring you want to exclude from the count, you can use a formula like this:
=COUNTIF(range,"<>*"&A1&"*")
Inside COUNTIF, the two asterisks and the not equal to operator (<>) are concatenated to the value in A1, and the formula works as before.
Exclude blanks
To exclude blank cells, you can switch to COUNTIFS function and add another condition like this:
=COUNTIFS(range,"<>*a*",range,"?*") // requires some text
The second condition means “at least one character”.
SUMPRODUCT function
Another way to solve this problem is with the SUMPRODUCT function and Boolean algebra . This approach has the benefit of being case-sensitive if needed. In addition, you can use this technique to target a number inside of a number, something you can’t do with COUNTIF.
To count cells that contain specific text with SUMPRODUCT, you can use the SEARCH function . SEARCH returns the position of text in a text string as a number. For example, the formula below returns 6 since the “a” appears first as the sixth character in the string:
=SEARCH( "a","The cat sat") // returns 6
If the text is not found, SEARCH returns a #VALUE! error:
=SEARCH( "x","The cat sat") // returns #VALUE!
Notice we do not need to use any wildcards because SEARCH will automatically find substrings. If we get a number from SEARCH, we know the substring was found. If we get an error, we know the substring was not found. This means we can add the ISNUMBER function to evaluate the result from SEARCH like this:
=ISNUMBER(SEARCH( "a","The cat sat")) // returns TRUE
=ISNUMBER(SEARCH( "x","The cat sat")) // returns FALSE
To reverse the operation, we add the NOT function :
=NOT(ISNUMBER(SEARCH( "a","The cat sat"))) // FALSE
=NOT(ISNUMBER(SEARCH( "x","The cat sat"))) // TRUE
We now have what we need to count cells that do not contain a substring with SUMPRODUCT. Back in the example worksheet, to count cells that do not contain “a” with SUMPRODUCT, you can use a formula like this
=SUMPRODUCT(--NOT(ISNUMBER(SEARCH("a",data))))
Working from the inside out, SEARCH is configured to look for “a”:
SEARCH("a",data)
Because data (B5:B15) contains 11 cells, the result from SEARCH is an array with 11 results:
{1;1;1;1;2;2;#VALUE!;#VALUE!;#VALUE!;#VALUE!;#VALUE!}
In this array, numbers indicate the position of “a” in cells where “a” is found. The #VALUE! errors indicate cells where “a” was not found. To convert these results into a simple array of TRUE and FALSE values, we use the ISNUMBER function :
ISNUMBER(SEARCH("a",data))
ISNUMBER returns TRUE for any number and FALSE for errors. SEARCH delivers the array of results to ISNUMBER, and ISNUMBER converts the results to an array that contains only TRUE and FALSE values:
{TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE}
In this array, TRUE corresponds to cells that contain “a” and FALSE corresponds to cells that do not contain “a”. This is exactly the opposite of what we need, so we use the NOT function to reverse the array:
NOT(ISNUMBER(SEARCH("a",data)))
The result from the NOT function is:
{FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE;TRUE}
In this array, the TRUE values represent cells we want to count. However, we first need to convert the TRUE and FALSE values to their numeric equivalents, 1 and 0. To do this, we use a double negative (–):
--NOT(ISNUMBER(SEARCH("a",data)))
The result inside of SUMPRODUCT looks like this:
=SUMPRODUCT({0;0;0;0;0;0;1;1;1;1;1}) // returns 5
With a single array to process, SUMPRODUCT sums the array and returns 5 as a final result.
One benefit of this formula is it will find a number inside a numeric value. In addition, there is no need to use wildcards to indicate position, because SEARCH will automatically look through all text in a cell.
Case-sensitive option
For a case-sensitive count, you can replace the SEARCH function with the FIND function like this:
=SUMPRODUCT(--NOT(ISNUMBER(FIND("A",data))))
The FIND function works just like the SEARCH function, but is case-sensitive. Notice we have replaced “a” with “A” because FIND is case-sensitive. If we used “a”, the result would be 11 since there are no cells in B5:B15 that contain a lowercase “a”. This example provides more detail .
Note: the SUMPRODUCT formulas above are more complex, but using Boolean operations in array formulas is a more powerful and flexible approach. It is also an important skill in modern functions like FILTER and XLOOKUP , which often use this technique to select the right data. The syntax used by COUNTIF is unique to a group of eight functions and is therefore not as useful or portable.
