Purpose

Return value

Syntax

=IMCONJUGATE(inumber)
  • inumber - The complex number in the form “x+yi”.

Using the IMCONJUGATE function

The Excel IMCONJUGATE function returns the conjugate of a complex number. For example, given the complex number “3+4i” as input, the function returns “3-4i” as output.

=IMCONJUGATE("3+4i") // returns "3-4i"

Excel handles complex numbers as strings formatted like “x+yi” or “x+yj”. Use the COMPLEX function to get the string representing a complex number.

Explanation

The conjugate of a complex number has the same real part and flips the sign of the imaginary part. If a complex number is written as “x + yi”, its conjugate equals “x - yi”. Typically, the conjugate appears in text with a horizontal bar over the complex number.

The conjugate of a complex number. - 1

The conjugate is used to divide a complex number by another. For example, let’s say you want to divide the complex number “x+yi” by another complex number “a+bi”.

How does one define complex division? - 2

We can convert this expression into a multiplication problem by multiplying the numerator and numerator by the conjugate of “a+bi”.

Complex division using the conjugate. - 3

In other words, the divisor is converted into a real number which we know how to divide by. This is equal to the following formula in Excel.

=IMPRODUCT(
    "x+yi",
    IMCONJUGATE("a+bi"),
    COMPLEX(1/IMREAL(IMPRODUCT("a+bi", IMCONJUGATE("a+bi"))), 0)
)

In practice, Excel provides the IMDIV function to perform complex division.

=IMDIV(COMPLEX(-11,29),COMPLEX(2,3)) // returns 5+7i

The conjugate is still useful to know because, aside from being the key to defining complex division, it also appears in other contexts in math, like factoring and solving polynomials.

Purpose

Return value

Syntax

=IMCOS(complex_num)
  • complex_num - The complex number in the form “x+yi”.

Using the IMCOS function

The Excel IMCOS function returns the cosine of a complex number. For instance, given “1 + 1i” as input, the function returns a complex number equal to the cosine of the input.

=IMCOS(COMPLEX(1,1)) // returns 0.833730025131149-0.988897705762865i

Given real number input, the function behaves like the cosine function. For instance, when π/2 + 0i is provided as input, the function returns -3.49148133884313E-15 (approximately zero). The cosine of π/2 is zero, but due to floating-point precision, it returns a very small number close to zero.

=IMCOS(COMPLEX(PI()/2,0)) // returns approximately 0

Explanation

Mathematically, the cosine of a complex number can be represented using a combination of the standard and hyperbolic trigonometric functions.

Cosine of a complex number. - 4

If B6 contains a complex number in the form “x+yi”, this is equivalent to the following formula.

=COMPLEX(
    COS(IMREAL(B6))*COSH(IMAGINARY(B6)),
    -SIN(IMREAL(B6))*SINH(IMAGINARY(B6))
)

Alternatively, the cosine of a complex number can also be represented using the exponential function, where “z=x+yi.”

Equivalent form of cosine of a complex number using the exponential function. - 5

If B6 contains a complex number in the form “x+yi”, this is equivalent to the following formula.

=IMDIV(
    IMSUM(
        IMEXP(IMPRODUCT(COMPLEX(0,1), B6)), 
        IMEXP(IMPRODUCT(COMPLEX(0,-1), B6))
    ),
    2
)