Explanation
The second sheet in the workbook, Sheet2, contains 1000 first names in the range B4:F203.
The COUNTIF function takes a range and a criteria. In this case, we give COUNTIF a range equal to all rows in Sheet2.
Sheet2!1:1048576
Note: an easy way to enter this range is to use the Select All button .
For criteria, we use a reference to C4, which contains “John”. COUNTIF then returns 15, since there are 15 cells in Sheet2 equal to “John”.
Contains vs. Equals
If you want to count all cells that contain the value in C4, instead of all cells equal to C4, add the wildcards to the criteria like this:
=COUNTIF(Sheet2!1:1048576,"*"&C4&"*")
Now COUNTIF will count cells with the substring “John” anywhere in the cell.
Performance
In general, it’s not a good practice to specify a range that includes all worksheet cells. Doing so can cause major performance problems, since the range includes millions and millions of cells. When possible, restrict the range to a sensible area.
Explanation
The range B7:B9 contains the sheet names we want to include in the search. These are just text strings, and we need to do some work to get them to be recognized as valid sheet references.
Working from the inside out, this expression is used to build a full sheet reference:
"'"&B7&"'!"&"1:1048576"
The single quotes are added to allow sheet names with spaces, and the exclamation mark is a standard syntax for ranges that include a sheet name. The text “1:1048576” is a range that includes every row in the worksheet.
After B7 is evaluated, and values are concatenated, the expression above returns:
"'Sheet1'!1:1048576"
which goes into the INDIRECT function as the ‘ref_text’ argument. INDIRECT evaluates this text and returns a standard reference to every cell in Sheet1 . This goes into the COUNTIF function as the range. The criteria is provided as an absolute reference to C4 (locked so the formula can be copied down column C).
COUNTIF then returns a count of all cells with a value equal to “mary”, 25 in this case.
Note: COUNTIF is not case-sensitive.
Contains vs. Equals
If you want to count all cells that contain the value in C4, instead of all cells equal to C4, you can add wildcards to the criteria like this:
=COUNTIF(INDIRECT("'"&B7&"'!"&"1:1048576"),"*"&C4&"*")
Now COUNTIF will count cells with the substring “John” anywhere in the cell.
Performance
In general, it’s not a good practice to specify a range that includes all worksheet cells. Doing so can cause performance problems, since the range includes millions and millions of cells. In this example, the problem is compounded, since the formula uses the INDIRECT function, which is a volatile function . Volatile functions recalculate on every worksheet change, so the impact on performance can be huge.
When possible, restrict ranges to a sensible size. For example, if you know data won’t appear past row 1000, you can search just the first 1000 rows like this:
=COUNTIF(INDIRECT("'"&B7&"'!"&"1:1000"),$C$4)
