Explanation
Background
A common annoyance with data is that it may be represented as text instead of numbers. This is especially common with dimensions, which may appear in one text string that includes units, for example:
50 ft x 200 ft 153 ft x 324 ft Etc.
In a spreadsheet, it’s a lot more convenient to have actual numbers so that you can use them in calculations as you wish.
Extracting individual dimensions from a text representation can be done with formulas that combine several text functions.
Solution
In this case, it because we have both the “ft” unit and space characters (" “) included in the dimensions, it makes sense to remove these first. That will “normalize” the dimensions and simplify the formulas that do the actual extraction.
To remove both “ft” and " “, we are using this formula in cell C6, which contains two nested SUBSTITUTE functions:
=SUBSTITUTE(SUBSTITUTE(B5,"ft","")," ","")
This formula takes the original text, and first strips “ft” (in the inner ), then strips spaces with the outer SUBSTITUTE function.
The result is a dimension with just the “x” separating the two parts.
Now we can two relatively straightforward formulas to extract each part. To get the dimension on the left, D6 contains:
=LEFT(C5,FIND("x",C5)-1)
To get the dimension on the right, E6 contains:
=RIGHT(C5,LEN(C5)-FIND("x",C5))
Both of the formulas above extract the correct dimension by using FIND to locate the “x”. For more detail, see the related function links on this page.
Explanation
Sometimes you encounter data that mixes units directly with numbers (i.e. 8km, 12v, 7.5hrs). Unfortunately, Excel will treat the numbers in this format as text, and you won’t be able to perform math operations on such values.
To split a number from a unit value, you need to determine the position of the last number . If you add 1 to that position, you have the start of the unit text. This formula uses this concept to figure out where the unit of measure begins.
In the example shown, the formula in C5 is:
=MAX(ISNUMBER(VALUE(MID(B5,{1,2,3,4,5,6,7,8,9},1)))*{1,2,3,4,5,6,7,8,9})+1
This formula uses the MID function to extract the first 9 values in B5, one character at a time:
MID(B5,{1,2,3,4,5,6,7,8,9},1)
The array constant {1,2,3,4,5,6,7,8,9} is just a simple hack to extract up to 9 characters from a cell value into an array . The result looks like this:
{"8","0","v","","","","","",""}
We then use the VALUE function to convert numbers in text format to actual numbers. The result is:
{8,0,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!}
We run this array through ISNUMBER to get:
{TRUE,TRUE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE}
Then multiply that times another array with 9 numbers to get:
{1,2,0,0,0,0,0,0,0}
We use MAX to get the largest value, which is the position of the “last number”, then we add 1 to the position to get the “unit start” position. Finally, we use this position with standard LEFT and RIGHT functions to separate the numbers from the units:
=VALUE(LEFT(B5,C5-1)) // number
=TRIM(RIGHT(B5,LEN(B5)-C5+1)) // unit
Note that the hard-coded number array constant is a hack for convenience, and will only handle raw values up to 9 characters in length.
